[Excel07] Αποστολη email με pdf

[sotisanis]

Παιδια καλησπερα
Εχω φτιαξει αυτο το αρχειο και εχω κολλησει στο εξης:
Αποστολη με email αλλα αποθηκευμενο ως pdf με ημερομηνια
Την αποθηκευση ως pdf την εχω κανει σωστα και την αποστολη email σωστα
Αλλα την αποστολη email ως pdf δεν μπορεσα να την κανω διοτι δεν χρησιμοποιω το outlook αλλα το Thunderbird

δεν μπορεσα να βρω πουθενα την λυση!!!

[Tasos]

Καλησπέρα!
Σωτήρη δοκίμασε:

Sub testMail()
'Για να στείλουμε e-mail σε περισσότερους παραλήπτες διαχωρίζουμε τις διευθύνσεις με κόμμα.
'Με τον ίδιο τρόπο μπορούμε να επισυνάψουμε περισσότερα αρχεία.

    SendMailPerThunderBird _
            strTo:="sotisanis1@company.com,sotisanis2@company.com", _
            strCC:="sotisanisMain@company.com", _
            strSubject:="Γειά σου!", _
            strBody:="Πάμε στο σχολείο;" & vbLf & "Σε περιμένω...", _
            strAttachments:="C:\Users\Admin\Desktop\Book1.xlsx,C:\Users\Admin\Desktop\Book2.xlsx"
End Sub

Public Sub SendMailPerThunderBird( _
       ByVal strTo As String, _
       ByVal strCC As String, _
       ByVal strSubject As String, _
       ByVal strBody As String, _
       ByVal strAttachments As String)

    Dim strProgPath As String
    Dim strArgs As String
    
    ' Προσάρμοσε τη διαδρομή του εκτελέσιμου αρχείου 'thunderbird.exe' αν χρειαστεί.
    ' strProgPath = Chr(34) & Environ("ProgramFiles(x86)") & "\Mozilla Thunderbird\thunderbird.exe" & Chr(34)
    
    ' Προσάρμοσε τη διαδρομή του εκτελέσιμου αρχείου 'thunderbird.exe' αν χρειαστεί.
    strProgPath = Chr(34) & "C:\Program Files (x86)\Mozilla Thunderbird\thunderbird.exe" & Chr(34)
    
    strArgs = " -compose ""to='""" & strTo _
            & "',cc='" & strCC _
            & "',subject='" & strSubject _
            & "',body='" & strBody _
            & "',attachment='" & strAttachments & "'"""

    Shell strProgPath & strArgs, vbNormalFocus
    
End Sub

Καλή συνέχεια!

Τάσος

[sotisanis]

Τασο καλησπερα ευχαριστω για την βοηθεια
Αρχικα δουλευει κανονικα αλλα θελω να κανω δυο διορθωσεις.
Αν προσεξες εχω βαλει να αποθηκευται ως pdf με την ημερομηνια και το ονομα του αρχειου
Εγω θελω αυτο το pdf να το επισυνάπτω στο email αλλα καθε φορα αλλαζει η ημερομηνια
Και δευτερον πως μπορω ως κυριως κειμενο να βαλω πχ να μου εμφανιζει την περιοχη n37 εως p40

[sotisanis]

Καμοια βοηθεια ρε παιδια??

[sotisanis]

εχω βρει πως γινεται με το outlook αλλα δεν μπορω να το κανω με το thunderbird!!!
Λιγη βοηθεια ρε παιδια???

[sotisanis]

Παιδια το εκανα να επισυνάπτει το pdf
Αυτο που δεν βρηκα ακομα ειναι πως μπορω να βαλω για κειμενο τρεις γραμμες πχ Β40 Β41ΚΑΙ Β47
Καποια βοηθεια για αυτο?

Public Sub Save_ActSht_as_Pdf()
    ' Saves active sheet as PDF file.

    Dim Name As String
    
    Name = ThisWorkbook.Path & "\" & ActiveSheet.Name & " " & _
        Format(Now(), "dd.mm.yy") & ".pdf"
    
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=Name, _
        Quality:=xlQualityStandard, IncludeDocProperties:=True, _
        IgnorePrintAreas:=False, OpenAfterPublish:=False
End Sub
Sub testMail()
'Για να στείλουμε e-mail σε περισσότερους παραλήπτες διαχωρίζουμε τις διευθύνσεις με κόμμα.
'Με τον ίδιο τρόπο μπορούμε να επισυνάψουμε περισσότερα αρχεία.

    SendMailPerThunderBird _
            strTo:="sotisanis1@company.com,sotisanis2@company.com", _
            strCC:="sotisanisMain@company.com", _
            strSubject:=ActiveSheet.Name & " " & _
        Format(Now(), "dd.mm.yy"), _
            strBody:="Πάμε στο σχολείο;" & vbLf & "Σε περιμένω...", _
            strAttachments:=ThisWorkbook.Path & "\" & ActiveSheet.Name & " " & _
        Format(Now(), "dd.mm.yy") & ".pdf"
End Sub

Public Sub SendMailPerThunderBird( _
       ByVal strTo As String, _
       ByVal strCC As String, _
       ByVal strSubject As String, _
       ByVal strBody As String, _
       ByVal strAttachments As String)

    Dim strProgPath As String
    Dim strArgs As String
    
    ' Προσάρμοσε τη διαδρομή του εκτελέσιμου αρχείου 'thunderbird.exe' αν χρειαστεί.
    ' strProgPath = Chr(34) & Environ("ProgramFiles(x86)") & "\Mozilla Thunderbird\thunderbird.exe" & Chr(34)
    
    ' Προσάρμοσε τη διαδρομή του εκτελέσιμου αρχείου 'thunderbird.exe' αν χρειαστεί.
    strProgPath = Chr(34) & "C:\Program Files (x86)\Mozilla Thunderbird\thunderbird.exe" & Chr(34)
    
    strArgs = " -compose ""to='""" & strTo _
            & "',cc='" & strCC _
            & "',subject='" & strSubject _
            & "',body='" & strBody _
            & "',attachment='" & strAttachments & "'"""

    Shell strProgPath & strArgs, vbNormalFocus
    
End Sub

[sotisanis]

Παιδες το εκανα τελικα και αυτο αλλα εχω ακομα κατι

Ο κωδικας που αλλαξα στο body ειναι ο παρακατω

Range("O40") & vbLf & vbLf & Range("B40") & vbLf & Range("B41") & vbLf & vbLf & Range("B47") & vbLf & Range("B48").Value

Ομως πως θα βαλω πχ να ειναι το O40 σε bold με μεγαλυτερο μεγεθος και υπογραμισμενο?