[Συναρτήσεις] Πρόσθεση των 10 μικρότερων τιμών σε μία στήλη.

Καλημέρα σας.

Μία ίσως απλή ερώτηση, θέλω να κάνω.

Στη στήλη Α απο Α1 έως Α100, ας πούμε, έχω αριθμούς.

Υπάρχει κάποιος τύπος που να μου δίνει το άθροισμα των 10 μικρότερων τιμών σε αυτή την περιοχή;

Ευχαριστώ εκ των προτέρων.

[nasos23]

Καλημέρα σε όλους.
Οδυσσέα καλωσόρισες στην παρέα μας.

Δοκίμασε αυτό:

=SUM(SMALL($A$1:$A$100;{1;2;3;4;5;6;7;8;9;10}))

Φιλικά
Νάσος

[chris1978]

Καλημέρα
Eίναι ο ίδια συνάρτηση που πρότεινε ο Νάσος απλά μέσα σε παράδειγμα.

[Spirosgr]

Οδυσσέα Καλημέρα και καλώς ήρθες στην παρέα
Στο φύλλο που ακολουθεί θα δεις 4 εναλλακτικές μεθόδους για το ζητούμενο σου
Όλες δίνουν το ζητούμενο με την 3η μέθοδο να είναι η πιό ευέλικτη
Καλή συνέχεια

Καλημέρα σας.

Σας ευχαριστώ πολύ όλους και για το καλοσώρισμα και για τις λύσεις σας, οι οποίες ΟΛΕΣ δουλεύουν σωστά.
Συγνώμη αλλά δεν διατύπωσα σωστά την ερώτηση.
Θα ήθελα την πρόσθεση των 10 μικρότερων μοναδικών τιμών. Ο κάθε αριθμός, να λαμβάνεται υπόψιν ΜΟΝΟΝ μία φορά.
Μπορεί να γίνει;

[Spirosgr]

Επειδή είναι τελείως διαφορετική περίπτωση η μία από την άλλη
και με την παράκληση να είσαι σαφέστερος την επόμενη φορά
Η λύση στο πρόβλημα σου είναι η εξής:

Δημιουργείτε μια στήλη βοηθητική έστω Β1:B10
Σε κάθε κελί μπαίνει ένας αριθμός από το 1 έως το 10
Ο τύπος
=INDEX(summary_area;SMALL(IF(FREQUENCY(summary_are a;summary_area);ROW(summary_area)-ROW($A$1)+1);B1))
μπαίνει δίπλα στην βοηθητική στήλη στο C1 κελί
Ο τύπος εισάγετε με CTRL + SHIFT + ENTER
Σύρουμε κάτω
Έτσι έχουμε τις 10 μοναδικές μικρότερες τιμές και
Αθροίζουμε με SUM
Σημείωση:
Το πόσο θα σύρουμε κάτω εξαρτάτε από το πόσες τιμές θέλουμε να αθροίσουμε
πχ μέχρι το 7 οι 7 μικρότερες μοναδικές τιμές

[gr8styl]

Καλημέρα/καλησπέρα.
Καλώς όρισες Οδυσσέα.
Εγώ νομίζω ότι ακόμη δεν είναι απόλυτα σαφές το ζητούμενο. Γιαυτό παραθέτω δύο λύσεις

1) Αν θέλουμε το άθροισμα των 10 μικρότερων μοναδικών τιμών της λίστας ( δηλαδή των τιμών που υπάρχουν μια μόνο φορά), ο τύπος πίνακα
{=SUM(SMALL(IF(COUNTIF(A:A;A:A)=1;(A:A));ROW(1:10)))}
με την προϋπόθεση ότι υπάρχουν τουλάχιστον 10 μοναδικές τιμές.
Σημ τύπος πίνακα σημαίνει καταχώρηση με Ctrl+Shift+Enter και όχι σκέτο Enter. Τις { } δεν τις γράφουμε δημιουργούνται μόνες τους μετά την καταχώρηση

2) Αν πάλι θέλουμε το άθροισμα των 10 μικρότερων τιμών αλλά μια φορά η κάθε μία, χρησιμοποιούμε βοηθητική στήλη
Αν η λίστα είναι στην στήλη Α, τότε στο C1 βάζουμε τον απλό τύπο
=IF(AND(ISNUMBER(A1);COUNTIF(A$1:A1;A1)=COUNTIF(A: A;A1));A1;"")
και αντιγράφουμε προς τα κάτω μέχρι το τέλος της λίστας μας.
Η συνάρτηση που δόθηκε στην αρχή του θέματος από τον Νάσο, μας δίνει το άθροισμα.
Εναλλακτικά την κάνουμε συνάρτηση πίνακα (Ctrl+Shift+Enter)
{=SUM(SMALL(C:C;ROW(1:10)))} που προσωπικά την βρίσκω πιο κομψή.

Άλλη προσέγγιση είναι αξιοποιώντας την συνάρτηση RANK

Φιλικά
Θανάσης

Καλημέρα σας.

Aπό spirosgr
..Επειδή είναι τελείως διαφορετική περίπτωση η μία από την άλλη:.....

Η λύση με τις 2 βοηθητικές στήλες που μου πρότεινες, δουλεύει και σε ευχαριστώ για αυτό.
Εντελώς διαφορετική περίπτωση;;; Για να το λέει αυτό ένας Super Moderator του Φόρουμ, μάλλον θα είναι έτσι.

..και με την παράκληση να είσαι σαφέστερος την επόμενη φορά...

Με την δική μου παράκληση να είσαι λιγότερο αυστηρός την επόμενη φορά(Θυμήθηκα τον Δάσκαλό μου στο Δημοτικό) με δεδομένα και 2 άλλα πράγματα.
1) Δεν έχω εμπειρία και δεν ξέρω πως "κινούνται" τα φόρουμ...
2) Κατανοώντας ότι έθεσα λάθος το θέμα, στην απάντησή μου, ζήτησα συγνώμη

...Συγνώμη αλλά δεν διατύπωσα σωστά την ερώτηση.

Έπρεπε να κάνω και κάτι άλλο που δεν το έκανα;;

Θανάση,ευχαριστώ πολύ για την απάντησή σου. Προφανώς απο δικό μου λάθος, δεν είμαι σε θέση να δουλεψει αυτός ο τύπος.

=IF(AND(ISNUMBER(A1);COUNTIF(A$1:A1;A1)=COUNTIF(A: A;A1));A1;"")

Μάλλον κάτι κάνω λάθος....

Ευχαριστώ πολύ.

[gr8styl]

Αρχική Δημοσίευση από Οδυσσέας

Θανάση,ευχαριστώ πολύ για την απάντησή σου. Προφανώς απο δικό μου λάθος, δεν είμαι σε θέση να δουλεψει αυτός ο τύπος.

=IF(AND(ISNUMBER(A1);COUNTIF(A$1:A1;A1)=COUNTIF(A: A;A1));A1;"")

Μάλλον κάτι κάνω λάθος....

Ευχαριστώ πολύ.

Αγαπητέ Οδυσσέα,
δεν φταις εσύ αλλά ο δαίμονας του Copy/Paste (κατά το "ο δαίμονας του τυπογραφείου").

σβήσε το διάστημα μεταξύ ":" και "A" στην δεύτερη COUNTIF έτσι δηλαδή

=IF(AND(ISNUMBER(A1);COUNTIF(A$1:A1;A1)=COUNTIF(A:A;A1));A1;"")

Καλή βδομάδα σε όλους και όλες.

Θανάσης

[Spirosgr]

Καλημέρα
Δεν υπάρχει πρόθεση να "μαλώσω" κάποιον φίλε Οδυσσέα αλλά όπως ξέρεις η Ελληνική γλώσσα είναι περίεργη και πλούσια...
Από την εποχή του <<ηξεις, αφήξεις>> ένα κόμμα έπαιζε σημαντικό ρόλο στην έννοια των προτάσεων πόσο μάλλον μια λέξη
Άλλο πράγμα λοιπόν 10 μικρότερες τιμές (όπως άλλωστε αναφαίρετε και στον τίτλο ) και άλλο πράγμα 10 μικρότερες μοναδικές τιμές
Η διαφορετικότητα φαίνεται άλλωστε και από την "κατασκευή" των τύπων
Σε κάθε περίπτωση το να είναι η ερώτηση σαφής βοηθάει όλους
Χαίρομαι που σε βοήθησα πάντως και θα το ξανακάνω ευχαρίστως αν ζητηθεί