Διόρθωση ρουτίνας

[alex]

Καλησπέρα και Χρόνια Πολλά ευτυχισμένο το νέο έτος
Καλησπέρα σε όλη την παρέα του forum.
Eχω μια ρουτίνα sShowSurveyDays
Την ρουτίνα την καλώ από κάποια φόρμα .θέλω να μου ανοίγει απο την ρουτίνα ο ιnternet explorer.Τι πρέπει να συμπληρώσω για να ανοίξει .
Παραθέτω τον κώδικα.
Στο σημείο που κοκκινίζει χρειάζεται συμπλήρωμα.

Public Sub sShowSurveyDays()
'Ρουτίνα που εμφανίζει το σύστημα καταγραφής στοιχείων για το νηπιαγωγείο
Dim CurrentSysDate As Date, CurrentSysMonth, CurrentSysDay As Integer
Dim i As Integer, TmpName As String
CurrentSysDate = Date
CurrentSysMonth = Month(CurrentSysDate)
CurrentSysDay = Day(CurrentSysDate)
i = 0
Dim RcdNames As New ADODB.Recordset
    RcdNames.Open "Select * From " & CnstNameTable & " Where intDay=" & CurrentSysDay _
    & " and intMonth=" & CurrentSysMonth, CurrentProject.Connection, adOpenDynamic
    If Not RcdNames.EOF And Not RcdNames.BOF Then
        RcdNames.MoveFirst
            Do While Not RcdNames.EOF
            i = i + 1
                If i > 1 Then
                    TmpName = TmpName & " , " & RcdNames.Fields("SurveyDay")
                Else
                    TmpName = RcdNames.Fields("SurveyDay")
                End If
                RcdNames.MoveNext
            Loop
            Dim Response As Integer
            If i > 1 Then
               
            Else
                Response = MsgBox("ΚΑΛΗΜΕΡΑ ΣΗΜΕΡΑ ΠΡΕΠΕΙ ΝΑ ΕΝΗΜΕΡΩΣΕΤΕ ΤΟ  : " & TmpName _
                & vbNewLine & "ΣΥΝΔΕΘΕΙΤΕ ΣΤΟ ΙΝΤΕΡΝΕΤ. ", vbYesNo + vbDefaultButton1, " ΕΝΗΜΕΡΩΣΗ ΤΟΥSURVEY ")
            End If
            If Response = vbYes Then
                DoCmd.OpenForm ""
                
            End If
    End If
    RcdNames.Close
End Sub

Σημειώνω ότι δεν θέλω να ανοίγει μέσα απο φόρμα ο internet explorer διότι το έκανα και δεν με αφήνει να μπώ στο Σύστημα καταγραφής Α΄θμιας & Β΄θμιας Εκπσης.Μου ανοίγει την σελίδα αλλά όταν πάω να συμπλήρώσω τους κωδικούς με πετάει έξω.
Εάν μπορεί να δουλέψει απο φόρμα δεκτόν.Αν δεν μπορεί τι πρέπει να συμπληρώσω για να ανοίξει τουλάχιστον ο Internet Explorer.

Φιλικά
Αλέξανδρος

[Tasos]

Καλησπέρα Αλέξανδρε και χρόνια σου πολλά!

Δες έναν παραδειγματικό κώδικα για να ανοίξεις την εφαρμογή Internet Expolrer και να περιηγηθείς
σε μια ιστοσελίδα:

Option Explicit

Sub OpenIEApp()

' Δήλωση του Αντικειμένου "InternetExplorer" (Late Binding)
  Dim ie As Object

' Δήλωση του Αντικειμένου "InternetExplorer" (Early Binding)
' Προϋποθέτει την αναφορά "Μicrosoft Internet Controls" (ieframe.dll)
'    Dim ie As InternetExplorer


    'Δημιουργία εφαρμογής Internet Explorer
    Set ie = CreateObject("InternetExplorer.Application")

    'Περιήγηση σε μια ιστοσελίδα
    ie.Navigate2 "http://www.ms-office.gr/forum/"

    'Ορίζουμε την ιδιότητα του αντικειμένου σε "Ορατό"
    ie.Visible = True

    'Ο κώδικας περιμένει να φορτωθεί πλήρως η ιστοσελίδα

'    While ie.ReadyState <> READYSTATE_COMPLETE '(Early Binding)
'        DoEvents
'    Wend

    While ie.ReadyState <> 4
        DoEvents
    Wend

    ' Ο κώδικας που ίσως χρησιμοποιήσεις για να κάνεις κάτι στην ιστοσελίδα
    '.................
    '.................

    'Για να κλείσεις την εφαρμογή του internet Expolrer:
    ie.Quit
    'ή
    'ie.ExecWB OLECMDID_CLOSE, OLECMDEXECOPT_DONTPROMPTUSER, 0, 0 '(Early Binding)
    ie.ExecWB 45, 2, 0, 0    '(Late Binding)

    'Απαλοιφή του αντικειμένου από τη μνήμη
    Set ie = Nothing
End Sub

Φιλικά

Τάσος

[alex]

Καλησπέρα Τάσο

Τα έκανα τέλεια.Αφαίρεσα λίγο κώδικα εκεί στα κλεισίματα που αναφέρεις.
Δουλεύει άψογα και σε ευχαριστώ πολύ για την βοήθεια.Να σε ρωτήσω όμως και κάτι άλλο.
Εάν κάνω ένα πίνακα κατά συνέπεια και μια φόρμα για καταχώρηση του Username και Password του Login της ιστοσελίδας.
Πώς μπορώ σε μια ιστοσελίδα γνωρίζοντας τους κωδικούς της να τους τοποθετώ στην φόρμα της βάσης μου και να ανοίγει το Login της Ιστοσελίδας στο τελικό σημείο για να διαχειριστούμε τα δεδομένα της βάσης της ιστοσελίδας.
Όπως κάνουμε στην διαχείριση με τα gmail,hotmail,hayoo που μπορούμε να τα χειρίζομαστε απο μια βάση το εμπορικό email τύπου Ηotmail,Yahoo,κλπ.
Μήπως πρέπει να έχουμε στοιχεία του site;
Στοιχεία απο το Site δεν υπάρχουν γιατί είναι ένα site με βάση δεδομένων που κάθε σχολείο έχει τους δικούς του κωδικούς.

Φιλικά
Αλέξανδρος

[Tasos]

Καλημέρα!

Αλέξανδρε, δεν υπάρχει κάποια στάνταρ συνταγή στο ζητούμενο σου (Αυτόματη συμπλήρωση φόρμας HTML) επειδή το στυλ το στήσιμο και οι τυχόν περιορισμοί που έχει μια ιστοσελίδα με φόρμα εισαγωγής δεδομένων είναι πολυποίκιλα και δεν μπορούν να αντιμετωπιστούν όλα με τον ίδιο τρόπο.
Θα πρέπει κάποιος που έχει γνώσεις HTML, αντικείμενο InternetExplorer, HTML Library:

1. Να γνωρίζει την δόμηση της ιστοσελίδας
2. Να διαθέτει στοιχεία χρήστη (Όνομα χρήστη και κωδικό) ώστε να μπορέσει να κάνει τις απαραίτητες δοκιμές.

για να μπορέσει δημιουργήσει τέτοιου είδους αυτοματισμούς.

Αν τα 2 παραπάνω σημεία μπορούν να δημοσιευθούν τότε ίσως σου δοθεί κάποια απάντηση.

Φιλικά

Τάσος

[alex]

Τάσο καλησπέρα
Επειδή η ιστοσελίδα είναι του υπουργείου είναι αδύνατον να δημοσιευθούν στοιχεία και κωδικοί.Ευχαριστώ πάντως για το χρόνο σου και τις πληροφορίες.
Να σε ρωτήσω και κάτι ακόμη.
Όταν μου ανοίγει η ιστοσελίδα ενώ με αφήνει να κάνω Login και οποιαδήποτε χειρισμό της βάσης της μου βγάζει στο κάτω μέρος της ιστοσελίδας στη μπάρα το τριγωνάκι που λέει ότι η σελίδα έχει σφάλμα.Στις λεπτομέρειες του σφάλματος αναγράφει ότι ενδέχετε με την λειτουργεία του αυτοματισμού να προκαλέσει πρόβλημα στην ιστοσελίδα.Η ιστοσελίδα έχει δοκιμασθεί για google, firefox και κάτι άλλο.
Τι μπορεί να είναι αυτό;
Μήπως έχουν ρυθμίσει την ιστοσελίδα να μην δέχετε αυτοματισμούς;
Φιλικά
Αλέξανδρος

[Tasos]

Καλησπέρα!

Εμφανίζεται το σφάλμα που ανέφερες αν περιηγηθείς χειροκίνητα με Internet Explorer στη συγκεκριμένη ιστοσελίδα;

Τάσος

[alex]

Τάσο καλησπέρα

Οχι δεν εμφανίζεται χειροκίνητα.H ιστοσελίδα είναι(http://survey.sch.gr)

Φιλκά

Αλέξανδρος