[ Πίνακες ] Εξαγωγή πίνακα σε excel

[markosv]

υπάρχει τρόπος με ένα κουμπί να γίνει εξαγωγή του πινάκα σε excel αλλά να ορίζεις που να το αποθηκεύσεις κάθε φορά (προαιρετικά και ακόμα καλύτερα να δημιουργεί το φάκελο αν δεν υπάρχει)? προς το παρόν το έχω κάνει με macro με προεπιλεγμένη θέση αποθήκευσης αλλά δεν βολεύει

ευχαριστώ εκ των προτέρων

[Tasos]

Καλησπέρα.
Μάρκο δοκίμασε:

Sub test()
    On Error Resume Next
    DoCmd.OutputTo acOutputTable, "TableName", "Excel 97 - Excel 2003 Workbook (*.xls)"
    On Error GoTo 0

    'ο υπόλοιπος κώδικας

    '................
    '................
End Sub

Edit: Σε Access 2003 θα πρότεινα:

Option Compare Database
  Option Explicit
  Private Const MyDesktop = 0&
  Private Const ShOptions = 54&
   
   
  Private Sub cmdExportTable_Click()
  Dim fName As String
  fName = FolderBrowserDialog
  If fName <> vbNullString Then
      DoCmd.TransferSpreadsheet acExport, acSpreadsheetTypeExcel9, "Table1", fName & "\Table1.xls"
      End If
  End Sub
   
  Private Function FolderBrowserDialog() As String
      Dim oShell As Object
      Dim oFolder As Object
      Set oShell = CreateObject("Shell.Application")
      Set oFolder = oShell.BrowseForFolder( _
              hWndAccessApp, "Επιλέξτε φάκελο για να δημιουργήσετε  αντίγραφο ασφαλείας." & vbLf & _
              "αυτής της εφαρμογής και πατήστε 'ΟΚ'." & vbLf & _
              "Πατήστε 'Ακυρο'για να κλείσετε την εφαρμογή χωρίς αντίγραφο ασφαλείας." _
              & vbLf, ShOptions, MyDesktop)
      If Not oFolder Is Nothing Then
          FolderBrowserDialog = oFolder.Self.Path
      End If
      Set oFolder = Nothing
      Set oShell = Nothing
  End Function

Καλή συνέχεια!

Τάσος

[markosv]

εισαι αρχοντας !!!!! οτι ακριβώς έψαχνα