[Tasos]

Καλημέρα και Χρόνια πολλά σε όλους!

Δεν θα χρειαστεί κωδικοποίηση UTF-8 επειδή δεν αποστέλλεται κάποιο περιεχόμενο.

Λαμβάνοντας υπ' όψη ότι τα δεδομένα SMS εμπεριέχονται στη διεύθυνση (URL) και ότι ο διακομιστής SMS δεν μπορεί να τα διαχειριστεί τους χαρακτήρες Unicode ως απλό κείμενο , αυτό που πρέπει να γίνει είναι η κωδικοποίηση (Percent-decoding) των τμημάτων "title" και "message" ώστε να υπάρξει συμβατότητα στην αποκωδικοποίηση.


Προτείνω τα εξής:

Προσθήκη αναφορών :Microsoft Object HTML Library και Microsoft WinHTTP Services, Version x,x

Προσθήκη του παρακάτω κώδικα σε μια φόρμα:

Option Explicit
Option Compare Database

Private Function EncodeURL(strText As Variant)
    Dim oDoc As New HTMLDocument
    With oDoc.parentWindow
        .execScript "function encode(s) {return encodeURIComponent(s)}", "jscript"
        EncodeURL = .encode(strText)
    End With
    Set oDoc = Nothing
End Function

Public Function SendSMS(strUrl As String) As String
    Dim oweb As New WinHttp.WinHttpRequest
    oweb.Open "POST", strUrl, False
    oweb.send
    SendSMS = oweb.responseText
    Set oweb = Nothing
End Function

Private Sub BtnSendSMS_Click()
    Dim usr As String
    Dim psw As String
    Dim mobnu As String
    Dim title As String
    Dim message As String
    Dim strResult As String

    usr = "email@email.com"
    psw = "7fhd8y8erwe"
    mobnu = "35799999999"
    title = "Amlex"
    message = "Κάτι γραμμένο στα ελληνικά για δοκιμή"
    
    strResult = SendSMS( _
             "http://api.microsms.net/sendapidirect.asp?usr=" _
             & usr & "&psw=" & psw & "&dtype=1&title=" & EncodeURL(title) & _
             "&mobnu=" & mobnu & "&message=" & EncodeURL(message))
             MsgBox strResult, vbInformation, "SMS Result"
End Sub

Καλή συνέχεια και καλή Ανάσταση!

Τάσος