[kapetang]

Καλησπέρα

Βαγγέλη θα μπορούσες να προσθέσεις στη ΒΔ (DB2) μία φόρμα με ένα κουμπί και να χρησιμοποιήσεις τον παρακάτω κώδικα:

Private Sub cmdUpadateLinks_Click()
    Dim fullNameDB As String
    fullNameDB = PickDB()
    If Len(fullNameDB) > 0 Then
        UpdateLinks (fullNameDB)
    End If
End Sub

Public Function PickDB() As String
'Απαιτείται αναφορά στην Microsoft Office Object Library.
'Έκδοσης >=11.0

    With Application.FileDialog(3)

        'Επιλέγεται μόνο ένα αρχείο
        .AllowMultiSelect = False

        'Τίτλος του dialog box.
        .Title = "Διαλέξτε μία ΒΔ"

        'Ορισμός νέων φίλτρων.
        .Filters.Clear
        .Filters.Add "Access Databases", "*.MDB;*.accdb"
        .Filters.Add "Access Projects", "*.ADP"
        .Filters.Add "All Files", "*.*"

        'εμφάνιση πλαισίου διαλόγου και επιλογή
        If .Show = True Then
            PickDB = .SelectedItems(1)
        End If
        
    End With
End Function

Public Sub UpdateLinks(strBackEnd As String)
    'Ο κώδικας ισχύει για την περίπτωση που όλοι οι πίνακες
    'με τους οποίους συνδέεται η τρέχουσα ΒΔ βρίσκονται
    'σε μια ΒΔ (strBackEnd)
    '------------------------------------------------------------
    Dim db As DAO.Database, tbl As DAO.TableDef
    
    On Error GoTo errHandler
    
    Set db = CurrentDb
       
    For Each tbl In db.TableDefs
        If tbl.Connect <> "" Then
            tbl.Connect = ";DATABASE=" & strBackEnd
            tbl.RefreshLink
        End If
    Next
    
    MsgBox ("Οι σύνδεσμοι ενημερώθηκαν.")
    Exit Sub
errHandler:
    MsgBox Err.Description, vbCritical, "Error #" & Err.Number
End Sub

Σημειώνω ότι ο κώδικας θα πρέπει να αντιγραφεί στη φόρμα και ότι ονόμασα το κουμπί cmdUpadateLinks

Πατώντας το κουμπί θα εμφανιστεί ένα πλαίσιο διαλόγου επιλογής αρχείων, για να επιλέξουμε τη ΒΔ με τους πίνακες δεδομένων.