[Tasos]

Καλημέρα σε όλους!
Αγαπητέ Γιώργο, ο κώδικας που περιέχεται στο παράδειγμα σου προϋποθέτει την αναφορά
Microsoft Outlook Object Library (στον VBE Tools References) για να λειτουργήσει.

Εναλλακτικά θα μπορούσες να χρησιμοποιήσεις τον παρακάτω κώδικα στη φόρμα σου:

Option Compare Database
Option Explicit

Private Sub cmdContact_Click()
    Dim ol As Object, ContactItem As Object
    On Error Resume Next
    Set ol = CreateObject("Outlook.Application")
    Set ContactItem = ol.CreateItem(2&)
    With ContactItem
        .FirstName = Nz(Me.FirstName)
        '.LastName = Nz(Me.LastName) ' Φρόντισε να δημιουργήσεις το πεδίο "LastName" στη φόρμα.
        .HomeAddressStreet = Nz(Me.Address)
        .HomeAddressCity = Nz(Me.City)
        .HomeAddressState = Nz(Me.State)
        .HomeAddressPostalCode = Nz(Me.PostalCode)
        .Email1Address = Nz(Me.Email)
        .Display
    End With
     If Not ol Is Nothing Then Set ol = Nothing
End Sub

Private Sub cmdEmail_Click()
    Dim strSubj As String, strBody As String
    Dim ol As Object, oMail As Object
    strSubj = "Το θέμα (μπορεί να είναι ένα πεδίο της φόρμας)."
    strBody = "Το κείμενο (μπορεί να είναι ένα πεδίο της φόρμας)."
    On Error Resume Next
    Set ol = CreateObject("Outlook.Application")
    Set oMail = ol.CreateItem(0&)
    With oMail
        .To = Nz(Me.Email)
        .Subject = strSubj
        .Body = strBody
        .Display
    End With
    If Not ol Is Nothing Then Set ol = Nothing
End Sub

Private Sub Email_Change()
    Me.cmdEmail.Enabled = InStr(1, Me.Email.Text, "@")
End Sub

Private Sub FirstName_Change()
    Me.cmdContact.Enabled = Me.FirstName.Text <> ""
End Sub

Private Sub Form_Current()
    Me.cmdEmail.Enabled = InStr(1, Nz(Me.Email, ""), "@")
    Me.cmdContact.Enabled = Nz(Me.FirstName, "") <> ""
End Sub

Καλή συνέχεια!

Τάσος